# Copyright 2004-2005 André Malo
# Distributed under the terms of the GNU General Public License v2
# $Header$

inherit distutils

MY_PV="${PV/_alpha*/}"
MY_PR="r${PV/*alpha/}"
DESCRIPTION="A subversion commit notifier written in python"
SRC_URI="http://storage.perlig.de/svnmailer/${PN}-${MY_PV}-dev-${MY_PR}.tar.bz2"
HOMEPAGE="http://opensource.perlig.de/svnmailer/"
RESTRICT="nomirror"

IUSE=""
SLOT="0"
KEYWORDS="~x86"
LICENSE="Apache-2.0"
DEPEND=">=dev-lang/python-2.3
	>=sys-apps/sed-4"
RDEPEND=">=dev-lang/python-2.3
	dev-util/subversion
	"

DOCS="CHANGES NOTICE CREDITS"
S="${WORKDIR}/${PN}-${MY_PV}-dev-${MY_PR}"

src_install() {
	distutils_src_install --no-install-docs --no-replace

	docinto html
	dohtml -r docs/*{html,css,gif,jpg} docs/apidoc

	docinto sample
	dodoc sample/*{README,.conf,.txt}

	docinto sample/hooks
	for hook in sample/hooks/post-{commit,revprop-change,lock,unlock}; do
		sed -e "s,@@SCRIPTS@@,/usr/bin,g" \
			-i $hook \
			|| die "Could not modify $hook"
		dodoc $hook
	done

	doman docs/svn-mailer.1
}